Cambiar permisos en carpetas con icacls.exe

Si has cambiado permisos NTFS desde linea de comandos seguramente te suenen los comandos cacls, xcacls, setACL, fileACL...
Windows 7/2008 traen la utilidad de linea de comandos icacls (que funciona mucho mejor que su antecesor xcacls)
Por ejemplo si queremos añadir a los administradores locales permiso de Control Total sobre una carpeta (y subcarpetas):

icacls.exe "%ruta%" /Q /T /grant:r *S-1-5-32-544:(OI)(CI)(F)

Aunque se puede añadir permisos con el nombre del usuario/grupo, prefiero usar el SID para evitar problemas con los distintos idiomas (Administradores/Administrators).
Este comando crea una entrada para los Administradores locales en cada ACL de cada carpeta, pero si prefieres que las carpetas, subcarpetas y ficheros hereden los permisos de la carpeta padre:

icacls.exe "%ruta%" /Q /T /inheritance:e

En mi caso he necesitado añadir Administrators y SYSTEM a todas las subcarpetas de una unidad (sin modificar la carpeta padre), con un bucle 'FOR' lo conseguimos enseguida:

For /F "eol=* tokens=*" %%i IN ('dir "%ruta%" /b /AD') do icacls.exe "%ruta%\%%i" /Q /grant:r *S-1-5-32-544:(OI)(CI)(F) /grant:r *S-1-5-18:(OI)(CI)(F)

Pero, claro si quieres añadir este permiso es porque no tienes acceso, y los comandos anteriores te devolveran un Acceso Denegado.
Antes tendras que tomar posesion de las carpetas y ficheros:

takeown.exe /f "%ruta%" /R /A /D S

*(S en Windows ESP o Y en Windows ENG)

He preparado un bat para ejecutar los comandos segun cada necesidad:

@echo off
:inicio
set /P ruta=[carpeta a la que conceder permisos?]
echo.
echo [0-] NO CAMBIAR OWNER
echo [1-] ESTABLECER OWNER ADMINISTRATORS
echo.
echo [-2] AÑADIR ADMINISTRATORS A CARPETA Y SUBCARPETAS
echo [-3] AÑADIR ADMINISTRATORS A CARPETA
echo [-4] HABILITAR HERENCIA
echo [-5] AÑADIR SYSTEM A CARPETA
echo.
echo Ej. 04 SOLO HABILITAR HERENCIA. 14 OWNER + HABILITAR HERENCIA.
echo.
set /P val=[Que permiso quieres asignar?]

REM PROPIETARIO DE CARPETA Y SUBCARPETAS
if %val:~0,1%==1 takeown.exe /f "%ruta%" /R /A /D S
REM AÑADIR ADMINISTRATORS A CARPETA Y SUBCARPETAS
if %val:~1,1%==2 icacls.exe "%ruta%" /Q /T /grant:r *S-1-5-32-544:(OI)(CI)(F)
REM AÑADIR ADMINISTRATORS A CARPETA
if %val:~1,1%==3 icacls.exe "%ruta%" /Q /grant:r *S-1-5-32-544:(OI)(CI)(F)
REM HABILITAR HERENCIA
if %val:~1,1%==4 icacls.exe "%ruta%" /Q /T /inheritance:e
REM AÑADIR SYSTEM A CARPETA
if %val:~1,1%==5 icacls.exe "%ruta%" /Q /grant:r *S-1-5-18:(OI)(CI)(F)
pause
cls
goto inicio

De esta manera con asignar a la variable val 02,03,04,05,12,13,14,15 contemplo todas las opciones que me interesan.